OpenOffice.info

Ah a danke,alles klar :)

=VERSCHIEBUNG($Tabelle1.$B$9;MIN(WENN(ISTFEHLER(SUCHEN($Tabelle1.$A$9:$A$13;$Tabelle1.A1));100;ZEILE($Tabelle1.$A$9:$A$13)))-9;0)

=VERSCHIEBUNG($Tabelle1.$B$9;

Hallo,

da deine Stichworttabelle in Zeile 9 beginnt, muss die Verschiebung korrigiert werden.
Anstelle "-1" nun "-9" (fast am Ende der Formel)
[code]=VERSCHIEBUNG($Tabelle1.$B$9;MIN(WENN(ISTFEHLER(SUCHEN($Tabelle1.$A$9:$A$13;$Tabelle1.A1));100;ZEILE($Tabelle1.$A$9:$A$13)))-9;0)[/code]

Noch eine Anmerkung: Ausgangspunkt für die Verschiebung ist die Zelle B9 und nicht der ganze Bereich. DAher reicht [code]=VERSCHIEBUNG($Tabelle1.$B$9;[/code]

bei mir zeigt der gar nichts an,
was mache ich falsch??

{=VERSCHIEBUNG($Tabelle2.$B$2;MIN(WENN(ISTFEHLER(SUCHEN(Kategorien;A2));MaxKategorie+1;ZEILE(Kategorien)))-1;0)}

@mikeleb, [i]chapeau![/i]

[quote="mikeleb"]liefert entweder die Zeile (in der der Text gefunden wurde) oder 100 (als Dummy-Zeile)[/quote]
Ich hätte da noch 'nen kleinen Verbesserungsvorschlag anzubringen. Wenn in [i]mikelebs[/i] Formel

[list=1][*] im Dialog [i]Namen verwalten[/i] für den Zellbereich [code]$Tabelle2.$A$1:$A$9999[/code] z.B. der Name [color=#0000FF][i]Kategorien[/i][/color] vergeben wird und
 
[*] im Dialog [i]Namen verwalten[/i] für den Term [code]MAX(NICHT(ISTLEER(Kategorien))*ZEILE(Kategorien))[/code] z.B. der Name [color=#0000FF][i]MaxKategorie[/i][/color] angelegt wird und
 
[*] die Konstante »[color=#008000]100[/color]« durch den Namen [color=#0000FF][i]MaxKategorie[/i][/color] ersetzt wird, [/list] erhält man die [color=#0040FF][b][i]Matrix-Formel (!)[/i][/b][/color] [code]{=VERSCHIEBUNG($Tabelle2.$B$2;MIN(WENN(ISTFEHLER(SUCHEN(Kategorien;A2));MaxKategorie+1;ZEILE(Kategorien)))-1;0)}[/code]
[b]Vorteile:[/b]
[list=i][*] Durch die Verwendung „sprechender“ Namen wird die Formel leichter lesbar.
[*] Bei wachsender Tabelle muss der zu verwendende Zellbereich an nur einer einzigen Stelle, nämlich im Dialog [i]Namen verwalten[/i] in der Definition des Zellbereichs [color=#0040FF][i]Kategorien[/i][/color] angepasst werden. Die in der Tabelle1 eingesetzten Formeln müssen nicht geändert werden![/list]
Beides ist im Interesse der zukünftigen Pflege der Anwendung und dürfte diese spätestens dann erheblich erleichtern, wenn die Details der Lösung längst vergessen sind.

Gruß
lorbass

WENN(ISTFEHLER(SUCHEN($Tabelle2.$A$1:$A$5;A1));100;ZEILE($Tabelle2.$A$1:$A$5))

Hallo,
zur Erklärung: Der Code-Teil
[code]WENN(ISTFEHLER(SUCHEN($Tabelle2.$A$1:$A$5;A1));100;ZEILE($Tabelle2.$A$1:$A$5))[/code]
durchforstet den Bereich $Tabelle2.$A$1:$A$5 auf das Vorhandensein des Textes aus A1. Dabei wird die Prüfung für jede Zelle des Bereiches durchgeführt und liefert entweder die Zeile (in der der Text gefunden wurde) oder 100 (als Dummy-Zeile). Anschließend wird das Minimum aller Werte genommen. Dabei können zwei Fälle auftreten
a) der Text wurde in einer Zelle (z. B. in $Tabelle2.$A$2) gefunden, dann liefert das Minimum den Wert 2
b) der Text wurde nicht gefunden, dann liefert das Minimum den Wert 100
Anschließend wird der Focus von $Tabelle2.$B$1 um entsptrechend viele Zeilen nach unten verschoben (bis zum gewünschten Eintrag oder eben bis zur Zelle B100, die leer sein sollte) und der dortige Wert angezeigt.
Leider wird bei diesem Verfahren anstatt einer leeren Zelle der Wert 0 angezeigt. Das lässt sich umgehen, indem du
a) in die Zelle $Tabelle2.$B$100 ein Leerzeichen setzt
b) Nullwerte nicht anzeigen lässt
c) den Formatcode anpasst: z. B. so Standard;;;@

=VERSCHIEBUNG($Tabelle2.$B$1;MIN(WENN(ISTFEHLER(SUCHEN($Tabelle2.$A$1:$A$5;A1));100;ZEILE($Tabelle2.$A$1:$A$5)))-1;0)

Hallo,

das Problemist nicht so ganz ohen, aber mir einer Matrixformel lösbar.
Gib in C1 folgende Formel ein:
[code]=VERSCHIEBUNG($Tabelle2.$B$1;MIN(WENN(ISTFEHLER(SUCHEN($Tabelle2.$A$1:$A$5;A1));100;ZEILE($Tabelle2.$A$1:$A$5)))-1;0)[/code]
und schließe sie mit [b]Shift+Strg+Enter[/b] ab.