[gelöst] Was bedeutet diese Fehlermeldung?

Antwort erstellen

BBCode ist eingeschaltet
[img] ist ausgeschaltet
[url] ist eingeschaltet
Smileys sind ausgeschaltet
Die letzten Beiträge des Themas
   

Ansicht erweitern Die letzten Beiträge des Themas: [gelöst] Was bedeutet diese Fehlermeldung?

Re: Was bedeutet diese Fehlermeldung?

von kilix » Sa, 01.07.2023 13:29

Hallo mikeleb,

habe das Problem gelöst! Die Spaltenformate müssen, wie folgt definiert werden (war ursprünglich meine Dummheit weil ich diesen Teil des Codes einfach aus einem anderen Makro kopiert hatte):

Code: Alles auswählen

	sSpaltenFormate="1/1/2/1/3/1"
Dass du zu einem anderen Ergebnis kamst lag daran, dass du nicht alle Informationen hast!

Aber egal, dein Korrekturversuch hat mich auf den richtigen Weg gebracht! Danke!

Re: Was bedeutet diese Fehlermeldung?

von mikeleb » Sa, 01.07.2023 09:50

Hallo,
wenn ich es richtig sehe, wird die 3. Spalte der csv als Text importiert.

Code: Alles auswählen

	sSpaltenFormate="1/1/2/2/3/2"
dadurch liefeert der Vergleich

Code: Alles auswählen

aDaten(i)(2)=wert2
stets FALSE. Die Zuweisung

Code: Alles auswählen

ergebnis=aDaten(i)(0)
wird nie erreicht.
Es müsste also durch

Code: Alles auswählen

	sSpaltenFormate="1/1/1/2/3/2"
behoben sein.

Re: Was bedeutet diese Fehlermeldung?

von kilix » Fr, 30.06.2023 22:00

Da bekomme ich leider auch den http-Fehler

Edit: habe dir einen Dateiauszug als Text per Mail gesandt. Du Brauchst diesen Text nur als CSV speichern.

Re: Was bedeutet diese Fehlermeldung?

von Karolus » Fr, 30.06.2023 21:42

kilix hat geschrieben: Fr, 30.06.2023 21:09 Hallo,
hier wäre die Datei. Aber leider kann ich sie nicht hochladen weil die Dateierweiterung csv nicht erlaubt ist. Nachdem auch txt nicht erlaubt ist habe ich sie gezipt. Aber auch damit hatte ich keinen Erfolg, ich erhielt die Meldung http-Fehler.

Bitte gib mir bekannt auf welchem Weg ich dir die Datei (sie hat nur 41Kb) zukommen lassen kann.
Ändere die Dateiendung auf .ods

Re: Was bedeutet diese Fehlermeldung?

von kilix » Fr, 30.06.2023 21:09

Hallo,
hier wäre die Datei. Aber leider kann ich sie nicht hochladen weil die Dateierweiterung csv nicht erlaubt ist. Nachdem auch txt nicht erlaubt ist habe ich sie gezipt. Aber auch damit hatte ich keinen Erfolg, ich erhielt die Meldung http-Fehler.

Bitte gib mir bekannt auf welchem Weg ich dir die Datei (sie hat nur 41Kb) zukommen lassen kann.

Re: Was bedeutet diese Fehlermeldung?

von mikeleb » Fr, 30.06.2023 19:04

Hallo,
kannst du uns so eine Datei hier zur Verfügung stellen. Dann lässt es sich einfacher analysieren.

Re: Was bedeutet diese Fehlermeldung?

von kilix » Do, 29.06.2023 13:21

Stimmt, da hätte ich genauer sein müssen!

Alle Werte und die ID sind ganzzahlig, numerisch. Wert1 und Wert2 werden richtig eingelesen und im If-Statement richtig erkannt und mit den Werten der Spalten 1 und 2 richtig verglichen.
Ich hatte im If-Statement die den Befehl print für die ID aus Spalte 0 und den Inhalt der Variablen ergebnis sowie der Variablen Wert1 und Wert2 ergänzt. Alle Inhalte der Spalte 0, 1 und 2 und Wert1 und Wert2 werden richtig erkannt. Nur die Variable ergebnis ist nach dem Befehl "ergebnis=aDaten(i)(0)" gleich 0.

Re: Was bedeutet diese Fehlermeldung?

von mikeleb » Do, 29.06.2023 10:18

Hallo,
für die fehlersuche ist es wichtig zu wissen, ob die ID (in der Spalte A) eine Zahl oder Text ist und ob die Vergleichswerte wert1 und wert2 richtig ausgelesen werden.
Wenn du Codezeilen

Code: Alles auswählen

'Vergleichswerte
	wert1=oDoc.Sheets.geByName("Parameter").getCellRangeByname("D4").value
	wert2=val(left(oDoc.Sheets.geByName("Parameter").getCellRangeByname("D6").string,3))+1859
ergänzt durch

Code: Alles auswählen

'Vergleichswerte
	wert1=oDoc.Sheets.geByName("Parameter").getCellRangeByname("D4").value
	wert2=val(left(oDoc.Sheets.geByName("Parameter").getCellRangeByname("D6").string,3))+1859
	msgbox "wert1: " & wert1 & chr(10) & "wert2: " & wert2
werden dir die Werte angezeigt.

Re: Was bedeutet diese Fehlermeldung?

von kilix » Mi, 28.06.2023 18:25

@mikeleb,

es hat wieder länger gedauert bis ich mich wieder mit OO beschäftigen konnte. Ich habe mein ursprüngliche Sub durch deine Sub (siehe oben) ersetzt. Leider ist der Ergebniswert 0 und nicht der gesuchte Indexwert. Das Problem liegt in diesem Bereich:

Code: Alles auswählen

	'Daten nach Vergleichswerten durchsuchen
	
	ergebnis=0	 	'wenn der gesuchte Wert SiKo_ID eine Zahl ist
	
	For i=0 to ubound(aDaten)
		If aDaten(i)(1)=wert1 AND aDaten(i)(2)=wert2 Then
			ergebnis=aDaten(i)(0)
		End If
	Next
	
	oDoc.Sheets(4).getCellRangeByname("G1").value=ergebnis
Durch die Schleife und das If-Statement wird in aDaten(i)(0) der richtige Wert eingelesen. Allerdings wird er nicht an die Variable ergebnis übergeben. Diese enthält den Wert 0 was nach obiger Definition wohl richtig ist da der gesuchte und gefundene Wert eine Zahl ist.
Nun brauche ich aber in der Zelle G1 den Wert der in aDaten(i)(0) steht denn das ist die ID mit der ich in der nächsten Sub die benötigten Zeilen herausfiltern kann.
Ich nehme an, dass mein Problem in der Zeile ergebnis=aDaten(i)(0) liegt. Was muss ich schreiben damit in ergebnis die gesuchte ID gespeichert wird?

In Gedanken überarbeite ich bereits die Datenübernahmen aus den beiden anderen CSV-Dateien. Diese enthalten die Daten der Vereine und der Mitglieder. In beiden Fällen sowohl die der aktiven als auch der nicht mehr aktiven und nur die benötige ich für mein System. Derzeit sortiere ich die übernommenen Zeilen nach dem Inaktivdatum und löschen dann die Zeilen die ein solches Datum enthalten. Diese Lösung habe ich auch als Makro mitgeschrieben. In Anlehnung an die oben angesprochene Lösung sollte es aber auch möglich sein überhaupt nur die aktiven Sätze zu übernehmen.

Re: Was bedeutet diese Fehlermeldung?

von kilix » So, 18.06.2023 22:41

Danke dir !

Re: Was bedeutet diese Fehlermeldung?

von mikeleb » So, 18.06.2023 21:47

Hallo,
dafür ist das Forum da ...
Respekt! und einfach weiter neugierig bleiben.

Re: Was bedeutet diese Fehlermeldung?

von kilix » So, 18.06.2023 20:31

Hallo mikeleb,

vielen Dank für deine Mühe! Dein Beispiel, insbesondere das If-Statement hat mir ein weiteres Tor zum Verständnis geöffnet. Ich hatte einmal schon vor direkt mit den Daten aus der csv-Datei eine Selektion zu machen aber mir fehlte die Möglichkeit detailierter auf Daten zuzugreifen - die ich jetzt habe.

Ich denke, dass ich einmal erklären sollte warum ich diese Arbeit mache:
Ich bin 78 Jahre alt und Pensionist/Rentner und möchte mein Gedächtnis und Hirn trainieren (besser als das mit Kreuzworträtsel und anderen Spielereien möglich ist). Bis vor 2 Jahren habe ich am PC vorbildähnliche 3D-Modelle für eine Eisenbahnsimulation konstruiert, die bei meinen Abnehmern gern verwendet wurden. Nachdem mir alles was ich sehr lange mache irgendwann langweilig wird habe ich eine andere Betätigung gesucht und, nachdem ich das auch schon früher (meist privat) gemacht habe, bin ich auf's Programmieren gestoßen. Früher hatte ich beruflich mit Basic+ von DEC zu tun und privat mit DBase III+, Acad, MS-Access und auch den alten Excel-Makros. Um hier anzuknüpfen habe ich begonnen mir FreeBasic anzueignen und damit diese Applikation entwickelt, die ich jetzt mit OO lösen möchte.
Nach dem was ich bis jetzt gelernt habe denke ich, dass mir das auch möglich sein wird. Die Aktionen, die zwischen Dokumenten zu lösen sind, kann ich jetzt aus deinen Beispielen abnehmen bzw. ableiten. Das meiste andere sind Aufzeichnungen von Bildschirmbefehlen. Dabei habe ich auf das Studium der Grundlagen wie von z.B. von Andrew Pitonyak bewußt verzichtet (die Geduld dafür habe ich nicht mehr und würde mir das auch nur schwer merken). Allerdings wenn ich Beispiele suche dann suche ich auch darin wie auch bei Michael Dannenhöfer (StarBasicfaq.pdf). Mit einem Wort ich lerne durch Vergleiche von Beispielen und probieren.
Noch eine Ergänzung: diese Arbeit mache ich nur für mich, sie wird nie veröffentlicht werden!

Re: Was bedeutet diese Fehlermeldung?

von mikeleb » Sa, 10.06.2023 18:02

Hallo,
ich habe mal versucht zu verstehen, was du mit den Makros vor hast.
Dabei ist mir folgendes augefallen:
Als erstes wird das Makro SiKo_CSV_Import aufgerufen. Damit werden aus einer csv-Datei Daten des Bereichs A1:C500 in den Bereich K3:M502 deiner odt-Datei kopiert.
Dann folgt das Makro SiKo_ID_finden. Hier wird nun in den Bereich J3:J500 (ggf. auch kleiner) eine Formel geschrieben, die die Einträge der Spalte L und M analysiert. Dann wird in die Zelle G1 eine Formel geschrieben, die aus dem Bereich J4:M500 genau einen Wert heraussucht und dann wird dieser Wert anstelle der Formel in die Zelle G1 übertragen.
Anschließend wird der Zellbereich J1:M500 gelöscht.
Wenn ich das so richtig verstanden habe, wäre es doch sinnvoller (und schneller) per Makro die csv-Datei nach der Zeile zu durchsuchen, deren Spalte B mit dem Wert von Parameter.D$4 übereinstimmt, und Spalte C mit dem WERT(LINKS(Parameter.D$6;3))+1859. Dann der Wert aus Spalte A in die Zelle G1 geschrieben werden und fertig.
Eine kurze Ergänzug der SiKo_CSV_Import würde das alles in einem Ruztsch erledigen:

Code: Alles auswählen

Sub SiKo_CSV_Import

	'Zugriff auf die aktuelle Datei
	oDoc=ThisComponent
	
	'Vergleichswerte
	wert1=oDoc.Sheets.geByName("Parameter").getCellRangeByname("D4").value
	wert2=val(left(oDoc.Sheets.geByName("Parameter").getCellRangeByname("D6").string,3))+1859
	
	'Öffnen der csv-Datei
	Dim args(1) as New com.sun.star.beans.PropertyValue
	args(0).Name= "FilterName"
	args(0).Value = "Text - txt - csv (StarCalc)"
	
	'ASCII-Codes 44 (Komma), 32 (Leerzeichen), 9 (Tabulator)
	'Mehrfachauswahl durch / trennen, z. B. 44/9
	sFeldSeparator="44"
	'ASCII-Codes 34 (doppelte Hochkomma), 39 (einfache Hochkomma)
	sTextBegrenzer="34"
	'Systemzeichensatz 0 - I: Unicode (UTF.8): 76
	sZeichensatz="76"
	'erste einzulesende Zeile
	sErste="1"
	'Spaltenformat für jede Spalte festlegen
	'Spalte/Format/Spalte/Format/...
	'Formate: 1 Standard, 2 Text, 3 Datum (MTJ), 4 Datum (TMJ), 5 Datum (JMT), 9 nicht importieren, 10 US-englisch
	'nicht aufgeführte Spalten werden als Standard importiert
	sSpaltenFormate="1/1/2/2/3/2"
	args(1).Name="FilterOptions"
	args(1).Value =sFeldSeparator & "," & sTextBegrenzer & "," & sZeichensatz & "," & sErste & "," & sSpaltenformate

	'Aktuelles Verzeichnis einlesen und Datei Sassen.csv öffnen
	surl = thiscomponent.url
	apfad = split(surl,"/")
	apfad(ubound(apfad)) = "sippungskopf.csv"
   	sURL = convertToURL(join(apfad,"/"))
   	oCSV = StarDesktop.LoadComponentFromURL(sURL, "_blank", 0, args())
   	
	'1: Auslesen der Daten in ein Array der Daten
	aDaten=oCSV.Sheets(0).getCellRangeByName("A2:C500").getDataArray
	
	'CSV-Datei schließen
	oCSV.close(false)
	
	'Daten nach Vergleichswerten durchsuchen
	
	ergebnis=0	 'wenn der gesuchte Wert SiKo_ID eine Zahl ist
	
	For i=0 to ubound(aDaten)
		If aDaten(i)(1)=wert1 AND aDaten(i)(2)=wert2 Then
			ergebnis=aDaten(i)(0)
		End If
	Next

	oDoc.Sheets(4).getCellRangeByname("G1").value=ergebnis
		
End Sub

Re: Was bedeutet diese Fehlermeldung?

von balu » Fr, 09.06.2023 20:03

Hallo kilix.

"Was bedeutet diese Fehlermeldung?"
Ist doch einfach.
A1:A10 ist ein Bereich.
K100:K110 ist ein Bereich.
(A1:A10;K100:110) ist eine Mehrfachselektion (Mehrfachbereich).
Es gibt Funktionen die können nicht auf Mehrfachselektion angewendet werden.

Deine aufgezeichneten Code-Segmente fallen unter den Begriff "Dispatcher". Das ist wohl manchmal wirklich ganz gut und schön, aber für umfangreichere Programme ist das einfach nur absoluter MIST! Und das bestätigt sich ja in deinem Falle. Du hast nur aufgezeichnet, aber Du weisst nicht genau was da eigentlich abläuft. Und jetzt stehst Du wie der Ochs vorm Scheunentor und weisst nicht weiter. Mit anderen Worten. "Lern richtig zu programmieren!"

Ich wette Du hast Karolus hiermit
Karolus hat geschrieben: Do, 08.06.2023 08:57 Dann stell dir mal vor du bekommst diese 500Zeilen-wurst (ohne Kontext) vorgesetzt und sollst das debuggen!
nicht richtig verstanden. Um aber dieses defizit auszugleichen setzen wir das mal Praktisch in die Tat um.
Im folgendem Code tritt dieser Fehler auf:
fehler.jpg
fehler.jpg (12.56 KiB) 8019 mal betrachtet
Jetzt sollst DU kilix den Fehler verstehen, suchen, finden und beseitigen. Viel Spaß auch dabei :lol: .

Code: Alles auswählen

	Public aLabels(99)
	Public BtnFaHelpIcon(1) as String

Sub MonatlicheFarben
	oHptDialog.setVisible(false)
	oHptDialog.isVisible(false)		
	wait 50
'--------------------------------------------------------------------------------------------------------------------------
	for lavf = 0 to 99
		aLabels(lavf) = oFarbDialog.getControl("Label" & lavf +1).Model
	next lavf
'--------------------------------------------------------------------------------------------------------------------------
	iFaPal = 0
	iFNa = 1
	Fuellen
'--------------------------------------------------------------------------------------------------------------------------
	oFarbDialog.Model.PositionX = 305
	oFarbDialog.Model.PositionY = 12
'--------------------------------------------------------------------------------------------------------------------------	
	ThisComponent.CurrentController.ColumnRowHeaders = false
	ThisComponent.CurrentController.ShowGrid = false
'--------------------------------------------------------------------------------------------------------------------------
	oLab102 = oFarbDialog.getControl("Label102").Model
	oLab102.backgroundcolor = BackFarbe
	oLab102.TextColor = FontFarbe	
'--------------------------------------------------------------------------------------------------------------------------
	oFarbDialog.getControl("Label103").Text = " " & BackFarbName
	oFarbDialog.getControl("Label104").Text = " " & FontFarbName
'--------------------------------------------------------------------------------------------------------------------------
	odraw = oPreview.drawpage
	Form1 = odraw.Forms.getbyIndex(0)
	oFormularButton = Form1.getbyname("Schaltfläche 1")
	oFormularButton.BackgroundColor = BackFarbe
	oFormularButton.TextColor =	FontFarbe	
	oFormularButton.Label = oMonat.SelectedItem
'--------------------------------------------------------------------------------------------------------------------------
	oFarbDialog.getControl("Label102").Text = "Datei ist nur für" & CHR(13) & oMonat.SelectedItem & " " & oJahr.SelectedItem & CHR(13) & "gültig!"	
'--------------------------------------------------------------------------------------------------------------------------
	oZellBereich = oPreview.getCellRangeByName("A1:G7")
	oZellBereich.CellBackColor = BackFarbe
	oZellBereich.charcolor = FontFarbe
'--------------------------------------------------------------------------------------------------------------------------
	oPreview.isvisible = True
'--------------------------------------------------------------------------------------------------------------------------
	myView4 = ThisComponent.CurrentController
	oSheet4 = ThisComponent.Sheets(2)
	myView4.setActiveSheet(oSheet4)
'--------------------------------------------------------------------------------------------------------------------------	
	BtnFaHelpIcon(1) = "sHilfe.png"
	oFarbDialog.Model.GetByName("BtnHelpFarbe").ImageURL = tempInit & "/" & BtnFaHelpIcon(1)
	oFarbDialog.setVisible(true)
	oFarbDialog.isVisible(true)	
'--------------------------------------------------------------------------------------------------------------------------
end sub
'
'###########################################################################################################################
'
sub MonatlicheFarbenBeenden	
	myView3 = ThisComponent.CurrentController
	oSheet3 = ThisComponent.Sheets(3)
	oPreview.isvisible = False
	myView3.setActiveSheet(oSheet3)	
'--------------------------------------------------------------------------------------------------------------------------
	oHptDialog.Model.PositionX = 11
	oHptDialog.Model.PositionY = 12
'--------------------------------------------------------------------------------------------------------------------------
						BruchStatus
'--------------------------------------------------------------------------------------------------------------------------
	For fapin = 1 to 6
		oLab300 = oHptDialog.getControl("Label" & fapin +300).Model
		oLab300.backgroundcolor = HintergrundFarbe
		oLab300.TextColor = SchriftFarbe
	next fapin
'--------------------------------------------------------------------------------------------------------------------------
		oHptDialog.getControl("Label305").Text = " " & CHR$(13) & oMonat.SelectedItem
		oHptDialog.getControl("Label306").Text = "Datei ist nur für" & CHR(13) & oMonat.SelectedItem & " " & oJahr.SelectedItem & CHR(13) & "gültig!"	
'--------------------------------------------------------------------------------------------------------------------------	
	for btnicoi = 1 to 9
		oHptDialog.Model.GetByName(BtnHilfe(1, btnicoi)).ImageURL = tempInit & "/" & btnico(2)
	next btnicoi
'--------------------------------------------------------------------------------------------------------------------------
	oHptDialog.Model.Step = 3
End Sub
'
'###########################################################################################################################
'
Sub FarbeSetzen(oEvent) 
	oLesen = oEvent.Source.Model.Name
	FabNr = Val(right(oLesen, len(oLesen) -5))
'--------------------------------------------------------------------------------------------------------------------------
	odraw = oPreview.drawpage
	Form1 = odraw.Forms.getbyIndex(0)
	oFormularButton = Form1.getbyname("Schaltfläche 1")	
'--------------------------------------------------------------------------------------------------------------------------			
		oZellBereich = oPreview.getCellRangeByName("A1:G7")
'--------------------------------------------------------------------------------------------------------------------------					
	if oFarbDialog.getControl("OptionButton3").Model.state = 1 Then 
		oFarbDialog.getControl("Label102").Model.backgroundcolor = FaLi(iFaPal, FabNr -1)
			oZellBereich.CellBackColor = FaLi(iFaPal, FabNr -1)
	
				BackFarbe = FaLi(iFaPal, FabNr -1)
				BackFarbName = FaLi(iFNa, FabNr -1)

					oFormularButton.BackgroundColor = FaLi(iFaPal, FabNr -1)
					oFarbDialog.getControl("Label103").Text = " " & FaLi(iFNa, FabNr -1)
'--------------------------------------------------------------------------------------------------------------------------
	else				
		if oFarbDialog.getControl("OptionButton4").Model.state = 1 Then
			oFarbDialog.getControl("Label102").Model.TextColor = FaLi(iFaPal, FabNr -1)
				oZellBereich.charcolor = FaLi(iFaPal, FabNr -1)
				
				FontFarbe = FaLi(iFaPal, FabNr -1)
				FontFarbName = FaLi(iFNa, FabNr -1)
				
					oFormularButton.TextColor = FaLi(iFaPal, FabNr -1)
					oFarbDialog.getControl("Label104").Text = " " & FaLi(iFNa, FabNr -1)
		end if
'--------------------------------------------------------------------------------------------------------------------------			
	end if	
end sub
'
'###########################################################################################################################
'
Sub LabelLesen(oEvent) 
	oLesen = oEvent.Source.Model.Name
	LaLe = Val(right(oLesen, len(oLesen) -5))
	oFarbDialog.getControl("Label101").Text = " " & FaLi(iFNa, LaLe -1)
end sub
'
'########################################################################################################
'
Sub LabelOff(oEvent) 
	oFarbDialog.getControl("Label101").Text = "" 
end sub
'
'########################################################################################################
'
sub ArtWechseln(oEvent)
	oArWe = oEvent.Source.Model.Name
	ArtWex = Val(right(oArWe, len(oArWe) -12))
	
	if ArtWex = 3 Then
		OpBu1 = 3
		OpBu2 = 4
			OptionenWechseln
'--------------------------------------------------------------------------------------------------------------------------
	else
		OpBu1 = 4
		OpBu2 = 3
			OptionenWechseln		
'--------------------------------------------------------------------------------------------------------------------------
	end if
end sub
'
'########################################################################################################
'
sub PaletteWechseln(oEvent) 
	oPaWe = oEvent.Source.Model.Name
	PalNr = Val(right(oPaWe, len(oPaWe) -12))
	
	if PalNr = 2 Then
		OpBu1 = 2
		OpBu2 = 1	
			OptionenWechseln
'--------------------------------------------------------------------------------------------------------------------------
				iFaPal = 2
				iFNa = 3
					Fuellen
'--------------------------------------------------------------------------------------------------------------------------
	else
		OpBu1 = 1
		OpBu2 = 2	
			OptionenWechseln
				iFaPal = 0
				iFNa = 1
				Fuellen
'--------------------------------------------------------------------------------------------------------------------------
	end if
end sub
'
'########################################################################################################
'
sub OptionenWechseln
		oOptBu1 = oFarbDialog.getControl("OptionButton" & OpBu1).Model
		oOptBu1.backgroundcolor = FaLi(0, 2) '= "&H008000" : FaLi(1, 2) = "Grün"
		oOptBu1.TextColor = FaLi(0,15) '= "&Hffffff" : FaLi(1,15) = "Weiß"		
			
		oOptBu2 = oFarbDialog.getControl("OptionButton" & OpBu2).Model
		oOptBu2.backgroundcolor = -1
		oOptBu2.state = 0
		oOptBu2.TextColor = 0
end sub
'
'########################################################################################################
'
sub Fuellen 
	for lafu = 0 to 99
		aLabels(lafu).backgroundcolor = FaLi(iFaPal, lafu)
		aLabels(lafu).HelpText = " " & FaLi(iFNa, lafu)
	next lafu
end sub
'
'########################################################################################################
'
Sub FarbenDialogEnde(oEvent) 
	oFaDiEn = oEvent.Source.Model.Name
	DlgEnd = Val(right(oFaDiEn, len(oFaDiEm) -13))
	
	If DlgEnd = 1 then
		bruch = 0
	else 
		bruch = 1		
	endif
		
   oHptDialog.setVisible(true)
   oHptDialog.isVisible(true)
   oHptDialog.isActive(true)
   oHptDialog.isEnabled(true)
   		
	WennFarbeHilfe
		oFarbDialog.setVisible(false)
		oFarbDialog.isVisible(false)	
	MonatlicheFarbenBeenden
end Sub
'
'########################################################################################################
'
sub WennFarbeHilfe
	if oDlgFarbeHilfe.isVisible() = true then
		oDlgFarbeHilfe.setVisible(false)
		oDlgFarbeHilfe.isVisible(false)	
	end if
end sub
'
'########################################################################################################
'
Sub BruchStatus
	if bruch = 0 then
		HintergrundFarbe = BackFarbe
		SchriftFarbe = FontFarbe
'--------------------------------------------------------------------------------------------------------------------------
	else
			HintergrundFarbe = HinterFarbe(XZaehler)
			SchriftFarbe = TextFarbe(XZaehler)			
'--------------------------------------------------------------------------------------------------------------------------
	end if
end sub


Gruß
balu

Re: Was bedeutet diese Fehlermeldung?

von kilix » Do, 08.06.2023 09:32

Genau das war der Grund weshalb ich den Code ursprünglich nicht gesendet habe - im Übrigen habe ich in meinem Post mit dem Makro einen Hinweis auf den Bereich gegeben in dem ich die Ursache vermute (mehr als vermuten kann ich nicht)!
Ich werde mir das ganze nochmals - sobald ich dafür Zeit habe - ansehen. Für mich sieht das eher wie eine Warnung aus denn nach dem Quittieren läuft das Makro fehlerfrei durch. Außerdem erscheint diese Meldung auch intermittierend, also gibt es zwischendurch offenbar keine Probleme.
Eine Idee kam mir jetzt mit dem Schreiben: vielleicht bleibt nach einem Makrodurchlauf irgend etwas zurück, das ich mir zwar nicht erklären kann, das aber beim nächsten Durchlauf zu dieser Meldung führt. Ich werde das so testen, dass ich das Makro ein paarmal in Folge und dann mit Abstand (andere Makros in der Zwischenzeit) ausprobieren. Trifft die Idee zu dann sollte die Meldung im zweiten Fall nicht kommen.
Ich melde mich wieder, bis dahin lassen wir das Kraut und die Rüben liegen.

Nach oben