OpenOffice.info

Code: Alles auswählen

Sub Schreiben(via AS String)

LF = CHR(13)

'Formulare zuweisen
oDoc = thisComponent
oForm = oDoc.drawpage.forms.getbyindex(0)
oSubAbt = oForm.getByName("SubAbteilung")
oSubVorwahl = oForm.getByName("SubVorwahl")
oSubKontakt = oSubAbt.getByName("SubKontakt")
oSubTelefon = oSubAbt.getByName("SubTelefon").getByName("TableTelNrn")
oSubMail = oSubAbt.getByName("SubMail").getByName("TableMailAdressen")

'Felder auslesen
Firma = oForm.getByName("txtFirma").Text
Abteilung_Position = oSubAbt.getByName("txtAbteilung/Position").Text
Anrede = Trim(oSubAbt.getByName("txtAnrede").Text)
Vorname = Trim(oSubAbt.getByName("txtVorname").Text)
weitere_Vornamen = Trim(oSubAbt.getByName("txtweitere Vornamen").Text)
Nachname  = Trim(oSubAbt.getByName("txtNachname").Text)
Namenszusatz = Trim(oSubAbt.getByName("txtNamenszusatz").Text)
Strasze = oForm.getByName("txtStraße").Text
PLZ = oForm.getByName("txtPLZ").Text
Ort = oForm.getByName("txtOrt").Text
Bezug2 = oSubKontakt.getByName("txtBezug").Text
Kundennummer = oForm.getByName("txtKundennummer").Text
Betreff = oSubKontakt.getByName("txtBetreff").Text
Inhalt = oSubKontakt.getByName("txtInhalt").Text
Datum_date = oSubKontakt.getByName("TableKontakte").getByName("Datum").Date
Vorwahl = oSubVorwahl.getByName("ONVorwahl").Text
Nummer = oSubTelefon.getByName("Nummer").Text
MailAdr = oSubMail.getByName("txtMailAdresse").Text
TelArt= oSubTelefon.getByName("Art").Text

If IsEmpty(Datum_date) Then
	MsgBox "Der Cursor markiert kein Schreiben!"
	GoTo Ende
EndIf

AdrZ8 = ""

'testen auf Fax bereit

If via="Fax" Then
	 If InStr(1, TelArt,"ax", 0)=0 Then
	 MsgBox "Der Cursor zeigt auf keine Faxnummer!"
	 GoTo Ende
	 EndIf
	 IF Vorwahl<>"" THEN AdrZ8="("+Vorwahl+") " 
	 AdrZ8="- via Fax: "+AdrZ8+Nummer+" -"
EndIf

'testen auf Email bereit

If via="Email" Then
	 If InStr(1, MailAdr,"@", 0)=0 Then
	 MsgBox "Der Cursor zeigt auf keine Mailadresse!"
	 GoTo Ende
	 EndIf
	 AdrZ8="- via E-Mail: "+MailAdr+" -"
EndIf

'Datumausgaben berechnen
Datum_value=DateValue(Right(Datum_date,2) & "." & Mid(Datum_date,5,2) & "." & Left(Datum_date,4))
Datum1 = Format(Datum_value, "dddd, dd. mmmm yyyy")
Datum2 = Format(Datum_value, "dd.mm.yy")

'Zuweisungen erstellen
AdrZ2 = Firma
IF Abteilung_Position<>"" Then AdrZ2 = AdrZ2+LF+Abteilung_Position
AdrZ3=""
IF Anrede<>"" THEN AdrZ3 = Anrede+" "
IF Vorname<>"" THEN AdrZ3=AdrZ3+Vorname+" "
IF weitere_Vornamen<>"" THEN AdrZ3=AdrZ3+weitere_Vornamen+" "
IF Nachname<>"" THEN AdrZ3=AdrZ3+Nachname
IF Namenszusatz<>"" THEN AdrZ3=AdrZ3+" "+Namenszusatz

AdrZ6 = PLZ + " " + Ort



Anrede_uoK="Sehr geehrte Damen und Herren"
IF Left(Anrede,1)="H" THEN Anrede_uoK="Sehr geehrter "+Anrede+" "+Nachname
IF Left(Anrede,1)="F" THEN Anrede_uoK="Sehr geehrte "+Anrede+" "+Nachname
IF Anrede="" AND Vorname<>"" THEN Anrede_uoK="Hallo "+Vorname

anSeite2 = Firma
IF Abteilung_Position <>"" THEN anSeite2 = anSeite2+", "+Abteilung_Position
IF Anrede <>"" THEN anSeite2 = anSeite2 + ", "+Anrede+" "+Nachname

IF Kundennummer<>"" THEN Bezug=Kundennummer+", "+Bezug2 ELSE Bezug=Bezug2

'Fax aufrufen und schreiben
path=createunoservice("com.sun.star.util.PathSettings")
shell("LW:\...\OpenOffice.org 3\program\soffice.exe",1," -n " & ConvertFromUrl(path.work) & "\...\Formbriefe\Fax1.odt")

wait 3000

StarDesktop.CurrentComponent.Title = Format(Datum_value, "yyyy-mm-dd")+" "+Betreff

docInfo = StarDesktop.CurrentComponent.DocumentInfo
docInfo.Title=Format(Datum_value, "yyyy-mm-dd")+" "+Betreff
docInfo.Subject=Bezug
docInfo.Keywords="an: "+AdrZ2+LF+AdrZ3+LF+Strasze+LF+AdrZ6+LF+AdrZ8
docInfo.Author="hampelmann"
docInfo.Description="an: "+LF+LF+AdrZ2+LF+AdrZ3+LF+Strasze+LF+AdrZ6+LF+AdrZ8

Marke = StarDesktop.CurrentComponent.getBookmarks()
Marke.getByName("AdrZ2").getAnchor.setString(AdrZ2)
Marke.getByName("AdrZ3").getAnchor.setString(AdrZ3)
Marke.getByName("AdrZ5").getAnchor.setString(Strasze)
Marke.getByName("AdrZ6").getAnchor.setString(AdrZ6)
Marke.getByName("AdrZ8").getAnchor.setString(AdrZ8)
Marke.getByName("Datum1").getAnchor.setString(Datum1)
Marke.getByName("Bezug").getAnchor.setString(Bezug)
Marke.getByName("Betreff").getAnchor.setString(Betreff)
Marke.getByName("Anrede").getAnchor.setString(Anrede_uoK)
Marke.getByName("Inhalt").getAnchor.setString(Inhalt)
Marke.getByName("Datum2").getAnchor.setString(Datum2)
Marke.getByName("anSeite2").getAnchor.setString(anSeite2)

If via="Brief" Then StarDesktop.CurrentComponent.getGraphicObjects.getbyname("Unterschrift").dispose()



Ende:
End Sub

Sub Brief

Schreiben("Brief")

End Sub

Sub Fax

Schreiben("Fax")

End Sub

Sub Email

Schreiben("Email")

End Sub