Seite 1 von 1

Verständnisproblem bei verschachtelten Operatoren

Verfasst: Mo, 14.05.2018 16:47
von fratso
Moin!

Ich versuche, folgende Zeilen in eine zu packen; leider mit mäßigem Erfolg.

=WENN(I83="ganz_oben";"-";"")
=WENN(UND(H83=0;G83>=0,5);"oben";"")
=WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";"")
=WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";"")

Weiß hier jemand Rat?

Gruß

Frank

Re: Verständnisproblem bei verschachtelten Operatoren

Verfasst: Mo, 14.05.2018 17:20
von Mondblatt24
Hallo,

Code: Alles auswählen

WENN(I83="ganz_oben";"-";WENN(UND(H83=0;G83>=0,5);"oben";WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";""))))

Gruß Peter

Re: Verständnisproblem bei verschachtelten Operatoren

Verfasst: Mo, 14.05.2018 17:46
von lorbass
Bei derartigen Gelegenheiten gehe ich etwa so vor:

Im ersten Schritt kopiere ich deine Formeln in eine Textdatei, die ich mit 'nem normelane Text-Editor bearbeiten kann. Dort bringe ich ein bisschen Struktur in die WENN-Formel:

Code: Alles auswählen

=WENN(I83="ganz_oben";
  "-";
  ""
)
WENN(UND(H83=0;G83>=0,5);
  "oben";
  ""
)
WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));
  "fast_unten";
  ""
)
WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));
  "ganz_unten";
  ""
)
Danach ersetze die leere Zeichenkette (»""«) im SONST-Zweig durch die komplette nächste WENN-Funktion:

Code: Alles auswählen

=WENN(I83="ganz_oben";
  "-";
  WENN(UND(H83=0;G83>=0,5);
    "oben";
    WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));
      "fast_unten";
      WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));
        "ganz_unten";
        ""
      )
    )
  )
)
Das kann ich dann so, wie's dasteht, in eine Calc-Zelle kopieren. Alternativ kann ich die Struktur wieder rausnehmen und die Formel als eine einzige Zeile nach Calc transportieren:

Code: Alles auswählen

=WENN(I83="ganz_oben";"-";WENN(UND(H83=0;G83>=0,5);"oben";WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";""))))
Um die Logik das Ganzen hab ich mich hier allerdings nicht gekümmert, weil ich keinen blassen Schimmer davon habe, was in den diversen Zellen steht und was in welchem Fall als Ergbnis rauskommen soll.

Gruß
lorbass

Re: Verständnisproblem bei verschachtelten Operatoren

Verfasst: Mo, 14.05.2018 18:30
von fratso
Aufgabe gelöst! Ich danke herzlich für die beiden schnellen Antworten.

Frank