ADRESSE-Funktion für Adressbereiche

[Mobbi]

Hallo Leute,

habe gerade ein Problem das ich selbst nicht gelöst bekomme. Hat jemand ne Idee wie es gehen kann?
Ich habe eine Datenmatrix in der ich
1. die Positionierung (Zeile) über =VERGLEICH(B7;B3:B5;0) erreiche z.B. Zeile 3
2. muss ich in dieser Zeile für einen bestimmten Wert/Parameter die Position (Spalte) bestimmen, um im
3. Schritt den Index zu erhalten.
Probleme habe ich beim 2. Schritt
Das geht ganz gut mit mit einer festen Adresse

=VERGLEICH(B8;C3:J3;0)

Nur bekomme ich es nicht hin den Suchbereich C3:J3 an eine veränderliche Zeile zu binden. z.B.C2:J2 usw.

mit der Fkt ADRESSE bekomme ich einzeladressen hin "=ADRESSE(G7+2;3)" und "=ADRESSE(G7+2;10)" ergibt $C$3 und $J$3 aber für einen Adressbereich geht das nicht. Anbei ne Beispieldatei

Grüße Mobbi

[Karolus]

Hallo

Code: Alles auswählen

=SVERWEIS( land ;$B$2:$J$5;VERGLEICH( index ;$B$2:$J$2;0);0)

Google mal "OOo-wiki Kreuztabelle"

Gruß Karo

[Mobbi]

Hallo Karolus,
danke für die schnelle Antwort.

Code: Alles auswählen

=SVERWEIS( land ;$B$2:$J$5;VERGLEICH( index ;$B$2:$J$2;0);0)

Google mal "OOo-wiki Kreuztabelle"

Den Index von Spalte und Zeile suchen und damit den Wert finden geht. Diesen Fall habe ich auch mit Kreuztabelle gelöst bekommen.
Ich habe aber nur die Position der Zeile und den Wert und benötige die Dazugehörige Spalte
Bekannt: Zeile 4, Wert x
Gesucht Spalte z.B. F

A B C D E F G H
1 . . . . . ^ . . .
2 . . . . . | . . .
3 . . . . . | . . .
4 - - -> - X . . .
5 . . . . . . . . .

Gruß Mobbi

[Karolus]

Hallo
Entschuldige, ich hab zuerst nicht so genau hingekuckt.

Code: Alles auswählen

=INDEX($B$2:$J$2;VERGLEICH( x ;VERSCHIEBUNG($B$1;VERGLEICH( "Land" ;$B$2:$B$5;0);0;1;9);0))

Gruß Karo

[Mobbi]

Auf die Funktion "VERSCHIEBUNG" wäre ich nicht gekommen. Der Name ist etwas irreführend, da ja nichts verschoben sondern ein Bezug auf eine y-x-Matrix erzeugt wird.

Mit VERSCHIEBUNG($B$1;L5;...) erzeugst Du den Zugriff auf den Zeilenbereich der benötigen Zeile und
mit VERGLEICH suchst Du dann die Position des Wertes raus.
einfach genial
Danke
Gruß Mobbi

[Karolus]

Hallo
Der "hintere" Vergleich verschiebt ab B1 in die richtige Zeile, der "Spaltenverschieber" dahinter bleibt 0, der Trick sind die folgenden optionalen Parameter von VERSCHIEBUNG .. 1;9 .. die erzeugen einen 1zeilige mal 9spaltigen Bereich ab dem vorne errechneten Zielpunkt →das ist der Bereich in dem der vordere VERGLEICH nach x sucht.

Gruß karo

[hiob]

hi Mobbi, für deine hochgeladene Datei geht für

Code: Alles auswählen

G8:=VERGLEICH(B8;INDEX(B2:J5;VERGLEICH(B7;B2:B5;0);0);0)-1

Code: Alles auswählen

G9:=INDEX(B2:J2;;VERGLEICH(B8;INDEX(B2:J5;VERGLEICH(B7;B2:B5;0);0);0))

[Mobbi]

Danke Leute habs heute umgesetzt und läuft.
Gruß Mobbi