Zeiten berechnen

[utari]

Ich habe viele Versionen versucht weil ich auch das Forum und das Internet abgesucht habe... es gibt viele Vorlagen jedoch keine Formel passt irgendwie und wenn ich diese versuche anzupassen gibt es Fehlermeldungen...

[paljass]

Tja utari,
Rechnen mit Datum und Zeit hat so seine Tücken, ich musst aber auch suchen, bis ich den Fehler fand.
Er liegt in der Berechnung "B4<=ZEIT(5;0;0)". Hier vergleichst du Äpfel mit Birnen oder aber auch Datumswerte mit Zeitwerten.
Der Eintrag in B4 (Datum) ergibt als interne Rechenzahl 40647,208333333300, der Zeitwert (Zeit(5;0;0) ergibt 0,208333333333, so dass deine Bedingung nie erfüllt sein wird.
Du musst also den o.a. Formelteil ändern in ZEITWERT(TEXT(B4;"HH:MM"))<=ZEIT(5;0;0), wobei ich mich über das Kleiner-Zeichen wundere, schreibst du doch

wenn dann das Arbeitsende nach oder gleich 5 Uhr ist

es müsste doch dann größer/gleich heißen?!?
Außerdem solltest du vielleicht die beiden Anführungszeichen am Ende der Formel in eine 0 (Null) ändern, damit du nicht wieder irgendwann Probleme beim Rechnen mit Text kriegst. Sicher ist sicher!

Gruß
paljass

[utari]

Danke klappt nun wunderbar und ich habe die Formel geändert in:

=(ZEIT(24;0;0)-A4)+WENN(ZEITWERT(TEXT(B4;"HH:MM"))>=ZEIT(5;0;0);ZEIT(5;0;0)-ZEIT(4;0;0);"")

Jetzt habe ich das Problem das in der summe der Zeiten in spalte d (D4-D14) ein Fehlercode 522 erscheint. Laut internet soll ich da in den Einstellungen iterationen erlauben was ich getan habe. Nun erscheint fehlercode523 und da stecke ich nun fest...

[paljass]

Hallo utari,

Jetzt habe ich das Problem das in der summe der Zeiten in spalte d (D4-D14) ein Fehlercode 522 erscheint. Laut internet soll ich da in den Einstellungen iterationen erlauben was ich getan habe. Nun erscheint fehlercode523 und da stecke ich nun fest...

Warum in Gottes Namen sucht man sowas im Internet? Dafür gibts doch erst mal die Programmhilfe und die sagt u.a.

522
Zirkuläre Referenz
Die Formel bezieht sich direkt oder indirekt auf sich selbst,...

Daran hättest du erkennen können, dass du in D14 eine Summe unter Einbeziehung der Zelle D14 bilden wolltest; das geht aber nun mal nicht. Also löscht du erst mal die Formel. Ja, löschen.
Danach musst du noch Änderungen an der Formel in D4 vornehmen.
Zeit(24;0;0) ergibt 0:00 Uhr. Wenn man davon dann 22:00 abzieht, bleiben -22 Std - dass ist nicht das, was du willst.
Also ersetzt du erstmal Zeit(24;0;0) durch 1.
Für Zeit(a4) gilt das selbe wie ich in meiner vorigen Antwort zu Zeit(B4) geschrieben hatte; das musst du durch Zweitwert(Text(A4;"HH:MM")) ersetzen.
Außerdem hatte ich geschrieben, dass du die Formel vorsichtshalber mit 0 statt mit "" abschließen sollst. Die gesamte Formel lautet also

Code: Alles auswählen

=1-ZEITWERT(TEXT(A4;"HH:MM"))+WENN(ZEITWERT(TEXT(B4;"HH:MM"))>=ZEIT(5;0;0);ZEIT(5;0;0)-ZEIT(4;0;0);0)

.
Die gibst du in D4 ein und kopierst sie bis D13.
Anschließend formatierst du D14 auf [HH]:MM und gibst die Formel

Code: Alles auswählen

=Summe(d4:D13)

ein.

Viel Erfolg
paljass

[balu]

Hallo utari,

Ich möchte damit zuerst die Zeit ausrechnen von Arbeitsbeginn bis 24 Uhr

OK, das haben wir ja abgehakt.


Aber bei einer Sache bin ich mehr als nur verwirrt.

(einmal 25% ein anderes mal 40%). Also einmal von 22 Uhr bis 0 Uhr und von 0Uhr bis 6 Uhr.

und wenn dann das Arbeitsende nach oder gleich 5 Uhr ist möchte ich eine stunde von 4 Uhr bis 5 Uhr hinzuzählen.

Also was hat das denn nun wieder zu bedeuten? Die 40% werden doch von 00:00 bis 06:00 verrechnet, oder gibt es da bei dir eine andere Berechnung die Du uns hier noch nicht wirklich richtig mitgeteilt hast?

Ich seh das nämlich so, aus Berufserfahrung:
Schichtzulage Nr.1: gleich 25% von 22:00 bis 24:00
Schichtzulage Nr.2: gleich 40% von 00:00 bis 06:00.
Und ab 06:00 is nix mehr mit Zulage!

Daraus ergibt sich folgende Berechnung bei der Beispielarbeitszeit.
Beginn: 22:00
Ende: 05:15
Schichtzulage Nr.1: 2,00 Std.
Schichtzulage Nr.2: 5,25 Std.
Rechenweg:
(24:00-Beginn{22:00})+(Wenn Ende >= 00:00 UND Ende >= 06:00, dann 06:00, sonst Wenn Ende >= 00:00 UND Ende <= 06:00, dann Ende-00:00, sonst nix {0})

Und als Formel sieht das ganze dann so aus.

Code: Alles auswählen

=1-ZEITWERT(TEXT(A4;"HH:MM"))+WENN((ZEITWERT(TEXT(B4;"HH:MM"))>ZEIT(0;0;0))*(ZEITWERT(TEXT(B4;"HH:MM"))>=ZEIT(6;0;0));ZEIT(6;0;0);WENN((ZEITWERT(TEXT(B4;"HH:MM"))>ZEIT(0;0;0))*(ZEITWERT(TEXT(B4;"HH:MM"))<=ZEIT(6;0;0));ZEITWERT(TEXT(B4;"HH:MM"))-ZEIT(0;0;0);0))

Für die Berechnung nach Mitternacht bis Arbeitsende wird sie ein wenig gekürzt.

Code: Alles auswählen

=WENN((ZEITWERT(TEXT(B4;"HH:MM"))>ZEIT(0;0;0))*(ZEITWERT(TEXT(B4;"HH:MM"))>=ZEIT(6;0;0));ZEIT(6;0;0);WENN((ZEITWERT(TEXT(B4;"HH:MM"))>ZEIT(0;0;0))*(ZEITWERT(TEXT(B4;"HH:MM"))<=ZEIT(6;0;0));ZEITWERT(TEXT(B4;"HH:MM"))-ZEIT(0;0;0);0))

Da ich ja noch immer verwirrt bin, hoffe ich das meine Formel dennoch hilfreich ist.




Gruß
balu