Ersten und letzten Buchstaben auslesen

[Likedeeler]

Guten Tag,

ich möchte mit Calc eine Namensliste so bearbeiten, dass eine Art Codierung entsteht.
Folgendes Muster soll hier angewandt werden:
Der erste und letzte Buchstabe soll gelesen und in eine neue Zelle geschrieben werden.

Beispiel:

Max = mx
Theodor = tr

Vielen Dank im Voraus,
der Likedeeler

[miesepeter]

Hallo,
z.B. mit Formel

=TEIL(A1;1;1)&RECHTS(A1;1)
oder
=LINKS(A1;1)&RECHTS(A1;1)

Umwandlung in Kleinbuchstaben:

=KLEIN(LINKS(A1;1)&RECHTS(A1;1))

Ciao

Edit: Oh, TrueColor war schneller!

[TrueColor]

Schau dir mal die Funktionen LINKS und RECHTS an.

Edit: oh, Miesepeter war schneller. umwandeln in Kleinbuchstaben mit KLEIN

[Likedeeler]

Vielen Dank,

die RECHTS- und LINKS-Funktionen helfen.
Ich komme allerdings nicht weiter und eröffne daher die gesamte Aufgabe:

Namen sollen codiert werden nach dem Schema:

- erster und letzer Buchstabe Vorname
- letzter Buchstabe Nachname
- Geburtsdatum - Tag
- Geburtsdatum - Monat


Karl-Theodor Schummelberg, 14.04.1913 --> klg1404


Mein Problem sind Namen, die mit Bindestich geschrieben sind. Es soll immer nur der erste Name zählen, egal was folgt.

Beispieldatei im Anhang.

Vielen Dank im Voraus,
der Likedeeler

[miesepeter]

- Geburtsdatum - Tag
- Geburtsdatum - Monat

=TEXT(D3;"TT")
=TEXT(D3;"MM")

Und mit dem &-Zeichen alles verbinden...

Mein Problem sind Namen, die mit Bindestich geschrieben sind. Es soll immer nur der erste Name zählen, egal was folgt.

Bin ich überfragt, vermutlich gibt's eine Lösung, die den Bindestrich erkennt. Übrigens: Gilt das dann auch noch für die Familiennamen???

Ciao

[Likedeeler]

Moin miesepeter,

also wie du es empfielst, klappt es.
Ich habe es so geschrieben:

Code: Alles auswählen

=KLEIN(LINKS(C3;1)&RECHTS(C3;1)&RECHTS(B3;1))&TEXT(D3;"TT")&TEXT(D3;"MM")

Wenn die "Bindestrich-Vorgabe" nicht aufgelöst wird, bleibt dies das Problem - aber das hier ist ja kein Sinn-Sucher-Forum...

Vielen Dank für die Hilfe!
der Likedeeler

[paljass]

Hi,

Code: Alles auswählen

=KLEIN(LINKS(C3;1)&WENN(ISTFEHLER(SUCHEN("-";C3));RECHTS(C3;1);TEIL(C3;SUCHEN("-";C3)-1;1))&RECHTS(B3;1))&TEXT(D3;"TTMM")

...funktioniert nur, wenn der Bindestrich ohne Leerzeichen eingegeben wird.

Gruß
paljass

[Likedeeler]

Hallo Paljass,

das ist ja super. Vielen Dank.

Mir fällt just noch ein, was ist, wenn der Vorname "Hans Peter", also ohne Bindestrich ist?
Kann man auf die selbe Weise auch das Leerzeichen "raushexen"?

Likedeeler

[TrueColor]

GLÄTTEN löscht überflüssige Leerzeichen, macht aus dem "Hans Peter" also einen "HansPeter" oder aus dem "Karl - Heinz" einen "Karl-Heinz"

[paljass]

Hi,
@TrueColor

GLÄTTEN löscht überflüssige Leerzeichen

Stimmt!

macht aus dem "Hans Peter" also einen "HansPeter"

Blödsinn! Woher sollte Calc den wohl wissen, dass das Leerzeichen überflüssig ist? Außerdem, wenn du dir "HansPeter" ansiehst, solltest du doch selbst erkennen, dass das Leerzeichen eben nicht überflüssig ist.
Also, erstmal probieren, dann posten!

Die Suche nach dem Leerzeichen muss noch irgendwie in die Formel eingebunden werden, ich probier noch ein bisschen rum, hab aber auch nichts dagegen, wenn sich andere hier "einmischen".

Gruß
paljass

[paljass]

So, jetzt mal die Lösung:

Code: Alles auswählen

=KLEIN(LINKS(C3;1)&WENN(ISTFEHLER(SUCHEN("[-| ]";C3));RECHTS(C3;1);TEIL(C3;SUCHEN("[-| ]";C3)-1;1))&RECHTS(B3;1))&TEXT(D3;"TTMM")

Der Suchbegriff lautet jetzt "[-| ]"; unter Extras - Einstellungen müssen reguläre Ausdrücke in Formeln erlaubt sein.
Die Anführungszeichen sind für die Funktion Suchen() notwendig, weil nur nach Text gesucht wird und der steht in Anführungszeichen.
Die eckigen Klammern gehören zu den regulären Ausdrücken; gesucht wird das was innerhalb der Klammern steht.
Gesucht wird - was Wunder - nach einem Minuszeichen/Bindestrich.
Der | gehört auch zu den regulären Ausdrücken; er trennt die Suchbegriffe voneinander.
Vor der schließenden eckigen Klammer steht noch ein Leerzeichen, weil danach ja auch gesucht werden soll.

Bin mal gespannt, was für Wortspiele noch auf uns zukommen
paljass

[paljass]

Hallo Leute,
lasst doch dieses Glätten() und Wechseln() aus dem Spiel. Damit kriegt man doch nie den letzten Buchstaben des ersten Namen, weil Calc nicht erkennen kann, wo der erste Name endet.
Außerdem Wim,

WENN(ISTFEHLER(SUCHEN("-";C3)) ; RECHTS(GLÄTTEN(C3);1)

sorgt doch dafür, dass bei einem Leerzeichen zwischen den Namen der erste Buchstabe des ersten Names und der letzte Buchstabe des zweiten Namens genommen wird; genau das wollte aber Likedeeler vermeiden.

Gruß
paljass

[TrueColor]

macht aus dem "Hans Peter" also einen "HansPeter"

Blödsinn!

Hast recht, ich hätte nochmal testen sollen, statt mich auf alte Erinnerungen zu verlassen. GLÄTTEN scheint (jetzt?) nur doppelte, führende und folgende Leerzeichen zu bereinigen.