Formatierung: Datengültigkeit Liste Matrixformel

[F3K Total]

Hallo zusammen,
leider habe ich keine Idee, wie ich folgendes Problem lösen kann:
Es geht um eine Arbeitszeittabelle. Dem Benutzer sollen, je nachdem ob gerade Arbeitsbeginn oder Arbeitsende eingetragen werden soll, verschiedene Uhrzeiten in der Datengültigkeit angeboten werden.
Beispiel:
Arbeitsbeginn, aktuelle Uhrzeit = 7:00 Uhr
Angebot in Datengültigkeit: 6:30, 6:35, 6:40, 6:45, ... 7:00 Uhr, also alle Zeiten von vor 1/2 Stunde bis jetzt, in 5 min Schritten.
Arbeitsende, aktuelle Uhrzeit = 17:00 Uhr
Angebot in Datengültigkeit: 17:00, 17:05, 17:10, 17:15, ... 17:30 Uhr, also alle Zeiten von jetzt bis in einer 1/2 Stunde, in 5 min Schritten.
Diese Zeiten ermittele ich mit diesen Matrixformeln
Arbeitbeginn:

Code: Alles auswählen

{=INDEX(HEUTE()+1/4+((ZEILE(A1:A193)-1)*(1/(24*12)));MTRANS(MAX(WENN((GANZZAHL(REST(JETZT();1)*24*12)+1)/(24*12)+HEUTE()=HEUTE()+1/4+((ZEILE(A1:A193)-1)*(1/(24*12)));ZEILE($A$2:$A$194);0))-{7;6;5;4;3;2;1});0)}

Arbeitende:

Code: Alles auswählen

{=INDEX(HEUTE()+1/4+((ZEILE(A1:A193)-1)*(1/(24*12)));MTRANS(MAX(WENN((GANZZAHL(REST(JETZT();1)*24*12)+1)/(24*12)+HEUTE()=HEUTE()+1/4+((ZEILE(A1:A193)-1)*(1/(24*12)));ZEILE($A$2:$A$194);0))+{-1;0;1;2;3;4;5});0)}

Die Formeln funktionieren gut, sie geben den aktuellen Timestamp zurück.
Nun zum Problem:
Die Liste der Datengültigkeit zeigt die Datumswerte im Double Format an:

V.png (7.25 KiB) 734 mal betrachtet

Ich suche also eine Lösung wie hier stattdessen formatierte Zeiten angezeigt werden können.
Meine Versuche der Matrixformel mit

Code: Alles auswählen

+Vorlage("Zeit")

die Formatvorlage "Zeit" zuzuweisen, waren nicht erfolgreich.

Gruß Rik

[F3K Total]

Hi HeritzP

die Zelle Double Format mit Wert() wandeln

Wie soll das gehen? Kannst Du bitte genau erklären, wie ich in der dropdown-Liste der Datengültigkeit eine Darstellung im Zeitformat [HH:MM] bekommen kann.
Gruß R

[clag]

Hallo F3K Total,

habe es mal mit TEXT() probiert und es scheint zu klappen
=TEXT(A2;"hh:mm")
und diese gewandelten Texte mit Gültigkeit anbieten

Zeit+Gültigkeit.ods

(9.28 KiB) 47-mal heruntergeladen

hoffe es hilft Dir

[F3K Total]

Hallo Clag,

hoffe es hilft Dir

Ja, sehr, es ist die Lösung! Dankeschön.
Wenn ich geahnt hätte, das eine als Datum formatierte Spalte, diesen Text wieder als Datum interpretiert und man dann damit rechnen kann ... Da wäre ich nicht drauf gekommen.
Die Formeln lauten nun:
Formeln gelöscht, siehe unten
Dies führt zwar dazu, dass auch das Datum in der Gültigkeitsliste angezeigt wird, aber wenn man mal über 00:00 hinaus Uhr arbeitet, geht es sonst nicht.
Ist auch kein Problem, die Tabellenspalte kann man wieder als Zeit formatieren:

V2.png (10.86 KiB) 707 mal betrachtet

EDIT: Ich konnte die Formeln deutlich vereinfachen:
Beginn

Code: Alles auswählen

{=TEXT((GANZZAHL(REST(JETZT();1)*288))/(288)+HEUTE()-(7-ZEILE($A$1:$A$7))/288;"TT.MM.JJJJ hh:mm")}

Ende

Code: Alles auswählen

{=TEXT((GANZZAHL(REST(JETZT();1)*288)+1)/(288)+HEUTE()+(ZEILE($A$1:$A$7)-1)/288;"TT.MM.JJJJ hh:mm")}

Gruß Rik

[Karolus]

Hallo

@Rik
Betrachte die Auswahl aus der Gültigkeitsliste als "normale Eingabe" in Calc.

Karolus

[F3K Total]

Hallo Karolus,
ach so! Na, dann ist es klar.
Danke!
Gruß Rik