Finde Lösung für Formel nicht. Kann jemand helfen?

[Magnasmarak]

Hallo zusammen,

ich suche eine Formel für folgendes Problem:

C 26 ist ein feststehender Wert
C 27 variert

C 28 soll folgendes anzeigen:

wenn C 27 >= (1*2)*C 26, dann "1"
wenn C 27 >= (2*3)*C 26, dann "2"
wenn C 27 >= (3*4)*C 26, dann "3"
usw.

Ich habe es als ewig lange Formel eingegeben und kam dann wegen des ERR 512 nicht weiter.

Hat jemand eine Idee für eine Formel?

Besten Dank

[mikeleb]

Hallo,

Code: Alles auswählen

=wenn(C27>= (3*4)*C26;3;wenn(C27 >= (2*3)*C26;2;wenn(C27 >= (1*2)*C26;1)))

[F3K Total]

Hallo,
oder als Matrixformel

Code: Alles auswählen

=MAX(($C$27>=(ZEILE($A$1:$A$3)*ZEILE($A$2:$A$4)*$C$26))*ZEILE($A$1:$A$3))

mit STRG+SHIFT+ENTER abschließen -->

Code: Alles auswählen

{=MAX(($C$27>=(ZEILE($A$1:$A$3)*ZEILE($A$2:$A$4)*$C$26))*ZEILE($A$1:$A$3))}

Gruß R

[Magnasmarak]

Vielen Dank an alle für die Mühe.

Die Wenn-dann Formel ist mir bekannt, da es aber nahezu unendlich funktionieren soll, funtkioniert es so leider nicht.

Bei der Matix Formel kommt als Ergebnis immer 3 raus, vielleicht mache ich einen Fehler?????

[F3K Total]

Ja, vermutlich.
Hast du die Formel mit STRG+SHIFT+ENTER abgeschlossen?
Anbei eine Lösung bis 100*101*C26

Code: Alles auswählen

=MAX(($C$27>=(ZEILE($A$1:$A$100)*ZEILE($A$2:$A$101)*$C$26))*ZEILE($A$1:$A$100))

Gruß R

[Magnasmarak]

Ich habe Deine Formel jetzt etliche Male eingefügt und den Cursor ans Ende der Befehlszeile gesetzt, dann Shift + STRG + Enter gedrückt.

Soweit ich es verstanden habe, sollten danach eckige Klammern um die Formel entstehen. Leider passiert das nicht.
Shift Taste ist nicht aktiviert, also festgestellt.....

[Magnasmarak]

Keine Ahnung weshalb, aber eben klappt es.


Vielen, vielen Dank....

[mikeleb]

Hallo,

das

usw.

hatte ich glatt überlesen ...
Einfacher sollte es gehen, wenn die Ungleichung direkt gelöst wird.

Code: Alles auswählen

=ABRUNDEN(WURZEL(0,25+C27/C26)-0,5;0)

[Magnasmarak]

WOW,

Respekt.

Danke sehr.