Kalenderwoche eingeben dann soll Datum erscheinen

[kutscher]

Hallo zusammen

ich habe um meine Wochenstunden zu schreiben in Excel eine Formel eingegeben, wenn ich die Kalenderwoche in eine Zelle eingebe erfolgt in der ersten Zelle das jeweilige Anfangsdatum und in der zweiten Zelle das Enddatum. Diese Formel beginnt mit Dinnday. Da ich aber jetzt auf Open Office umgestiegen bin funktioniert dies nicht mehr . Kann mir da bitte jemand weiterhelfen welche Formel ich eingeben muß um dies wieder zu erreichen.

[Stephan]

Kann mir da bitte jemand weiterhelfen welche Formel ich eingeben muß um dies wieder zu erreichen

Dann müßtest Du die Formel von Excel posten, weil ich nicht weiß welche Nebenannahmen dort einfließen, denn es ist unmöglich nur aufgrund der Angabe der Nummer der Woche ihr Anfangs- und Enddatum zu bestimmen, weil diese vom konkreten Kalenderjahr abhängen.
Im Übrigen ist mir die Funktion "Dinnday" unbekannt und auch eine Google-Suche liefert zunächst nichts.


Gruß
Stephan

[turtle47]

Hallo Kutscher,

schau mal hier:

http://www.daddyswonderland.de/excel/fo ... Ermittlung

unter:

"Datum des Montages einer vorgegebenen Kalenderwoche"


Die Formel funktioniert auch in OOo Calc.

Für den letzten Tag der Kalenderwoche mußt Du nur noch die Formel ein wenig umbauen und in eine weitere Zelle einbauen.

Viel Erfolg

Jürgen

Edit: Wenn in der Zelle B3 die Formel steht kannst Du in der zweiten Zelle auch =B3+TAG(7) eingeben.

[kutscher]

Hallo ihr zwei

vielen Dank erstmal für die prompten Antworten. Bei der Formel in Excel brauch ich nicht das Jahr in einer extra Zelle eingeben es ist gleich in der Formel mit drinnen. Jetzt will ich wissen ob das in Open Office auch so geht? Die Formel lautet =wenn(Summe(R1)=0;"";Dinday(2006;R1)). Ich brauch also nur das Jahr abändern schon weiß Excel wegen der Wochentage bescheid.

[Stephan]

die Lösung ist Dir bereits genannt worden oder ist es unmöglich das Du selbst das gewünschte Datum in die Formel einträgst? Du tust das bei DEiner doch auch, wie Du gerade schreibst.

Jürgens Hinweis/Vorschlag war:

=DATUM(2006;1;1)+(A1-WENN(WOCHENTAG(DATUM(2006;1;1);2)>4;0;1))*7-WOCHENTAG(DATUM(2006;1;1)+(A1-WENN(WOCHENTAG(DATUM(2006;1;1);2)>4;0;1))*7;2)+1

=wenn(Summe(R1)=0;"";Dinday(2006;R1))

Ja, ich kenne Dinday nach wie vor nicht, das ist entweder eine benutzerdefinierte Funktion oder ein Funktionsausdruck der unter benannte Bereiche eingetragen ist.


Gruß
Stephan

[turtle47]

Hallo Kutscher,

warum so einfallslos??

Du brauchst doch die Formel nur ein wenig umzubauen damit Du die Jahrezahl nicht in einer extra Zelle eingeben mußt.

Hier die Formel für 2006:

Code: Alles auswählen

=DATUM(2006;1;1)+(A1-WENN(WOCHENTAG(DATUM(2006;1;1);2)>4;0;1))*7-WOCHENTAG(DATUM(2006;1;1)+(A1-WENN(WOCHENTAG(DATUM(2006;1;1);2)>4;0;1))*7;2)+1

Die Formel geht vieleicht auch noch etwas kürzer, aber da bin ich nicht gerade der Spezialist drin. Aber Hauptsache es funktioniert.

Jürgen

Edit @Stephan: Hatte den gleichen Gedanken. War aber beim Schreiben durch ein Telefonat unterbrochen. Hatte erst nach dem Absenden gesehen, dass Du die gleiche Idee hattest. Sorry!

[kutscher]

Hallo

habe es nachdem ich die Nachricht geschrieben habe genauso gemacht wie ihr in eurer Formel und funktioniert einwandfrei. Bin halt noch nicht so ganz fit auf diesem Gebiet aber es wird schon noch werden.

Gruß
Christian

[Gert Seler]

Hallo zusammen,
steht das Datum des 1-1-2006 in A1, ist die Formel für den ersten
Wochentag der Kalenderwoche in B1 (40) kürzer :

=WENN(A1<>"";A1-WOCHENTAG(A1;2)+(B1*7)+1;"")

Das Datum mit dem "Zahlenblock" rechts und (-) Minustaste eintragen.
Bitte testen.

mfg
Gert

[Stephan]

Bitte testen.

die Formel stimmt für das Jahr 2006.
Allgemein hingegen stimmt sie nicht, beispielsweise:

Code: Alles auswählen

Jahr      [*]       Erste Kalenderwoche beginnt
2000   03.01.2000   03.01.2000
2001   08.01.2001   01.01.2001
2002   07.01.2002   31.12.2001
2003   06.01.2003   30.12.2002
2004   05.01.2004   29.12.2003
2005   03.01.2005   03.01.2005
2006   02.01.2006   02.01.2006
2007   08.01.2007   01.01.2007
2008   07.01.2008   31.12.2007
2009   05.01.2009   29.12.2008
2010   04.01.2010   04.01.2010

[*]
=WENN(A1<>"";A1-WOCHENTAG(A1;2)+(B1*7)+1;"")

Gruß
Stephan

[Gert Seler]

Hallo Stephan,
ich gelobe Besserung. Wahr wohl nicht das gelbe vom Ei.
Hier mein zweiter Vorschlag. In A3 steht das Datum vom ersten Tag des Jahres (01-01-2006) formatiert gleich NN, TT.MM.JJJJ, in C2 steht die Zahl der KW (40) deren erster Wochentag (Monatg) gesucht wird.
Die Formel :

=WENN(UND($A$3<>"";$C$2<>"";KALENDERWOCHE($A$3;2)<>1);$A$3+($C$2*7)-WOCHENTAG($A$3;2)+1;$A$3+($C$2*7)-WOCHENTAG($A$3;2)-6)

Ist zwar etwas lang, sollte aber so jetzt funktionieren.
Zur Integration in Excel ist darauf zu achten, das dort die "Din_Kalender-
Wochen" Funktion arbeitet. Ebenso ist die Kalenderwoche ohne Typ (hier ;2) einzutragen.

Mit freundlichen Grüssen
Gert

[FranzX]

Hallo zusammen,

probiert mal folgende Formel:

In A2 steht das Datum vom ersten Tag des Jahres (01-01-2006) formatiert gleich NN, TT.MM.JJJJ, in A13 steht die Zahl der KW (1) deren erster Wochentag (Monatg) gesucht wird.


=DATUM(JAHR(A2);1;4)-WOCHENTAG(DATUM(JAHR(A2);1;4);3)+(A13-1)*7


Wenn's nur das laufende Kj. betrifft, geht auch folgende Formel:

=DATUM(JAHR(HEUTE());1;4)-WOCHENTAG(DATUM(JAHR(HEUTE());1;4);3)+(A13-1)*7

TIPP:
Das neu erschienene Buch des C&L-Verlags:
OpenOffice.org Calc - Formeln und Funktionen.

Es enthält mehr als 200 sofort einsetzbare Formeln, viele Beispiele für bedingte Formatierungen
und Zahlenformate sowie einen ausführlichen Kurs zum Arbeiten mit Formeln und Funktionen.

Mehr dazu unter: http://www.cul.de/oocalc.html


Viele Grüße
FranzX