OpenOffice.info

Möchte eine Reihe von Daten in eine Rangfolge bringen, allerdings will das mit der Formel RANG nicht so recht klappen.
In Einzelfällen stimmt das Ergebnis, aber es kommen auch oft Positionen doppelt vor.

Habe mal meine Versuche / Anfänge in den Anhang gepackt, vlt. könnt ihr mir ja meinen Fehler aufzeigen, denn ich denke vom Prinzip her sollte es ja der richtige Weg sein.

Mfg Moses

Hallo,
=RANG(Tabelle1.E3;Tabelle1.E3:E27)
du musst auf jeden Fall IMMER $E$3:$E$27 verwenden, also den Bezug absolut, damit dieser sich beim runter kopieren nicht ändert
also_
=RANG(Tabelle1.E3;Tabelle1.$E$3:$E$27)

Ich würde den Rang in der Tabelle1 ganz vorne bestimmen
zusätzlich würde ich die =Zeile() dazu benutzen um keine doppelten Werte zu bekommen.
Dann kannst du die sortierte Liste per =Sverweis() erzeugen
siehe Anhang
Holger

Hi Echo,

vielen Dank für deinen Hinweis.
Wenn doch nur alles so einfach wäre. Meinst du mit dem sverweis, dass das Programm die Tabelle selber erstellt?
Das wäre ja zu schön, sieht allerdings auf den ersten Blick auch kompliziert aus.

Hallo,
ja die habe das einfach in deine Tabelle eingebaut
in Hilfsspalte Tabelle1! Spalte A wird der Rang gesucht, dazu +zeile()/100 um doppelte Werte zu vermeiden.

Die [sortierte] Reihenfolge bekomme ich jetzt mit mit der Funktion
KKLEINSTE(Tabelle1.$A$3:$A$27;1)
KKLEINSTE(Tabelle1.$A$3:$A$27;2)
.......................................;3 ;4 ;5 usw.
Für 1;2;3;4;5 setze ich zeile(a1) ein; der Wert beginnt mit 1 und erhöht sich automatisch beim runter kopieren
KKLEINSTE(Tabelle1.$A$3:$A$27;ZEILE(A1))

Damit bekomme ich beim runter kopieren eine sortierte Rangliste der Zeilen.

Jetzt kommt =SVerweis() ins Spiel:
Schau dir die Formel in Rangfolge.C3 an.
Dort habe ich =sverweis() eingebaut und diese Formel als Suchkriterium eingesetzt.
Beim runter kopieren erzeugt der Sverweis() jetzt eine nach dem Rang sortierte Liste.

Gruß Holger

Na ich werd morgen mal die Tabelle hochladen und die zweite kann ich ja dann mal mit dem sverweis versuchen.

So hatte die letzten Tage keinen I-Net Zugang.
Hab jetzt die Tabelle mal soweit fertig gestellt, so wie wir sie für das Projekt benötigen.

Aktuell ist es in der Rangliste ja so, dass bei gleichen Werten der gleiche Rang vergeben wird, dann aber die folgenden Ränge quasi übersprungen werden.
Ist es möglich, dass zwar gleiche Werte gleiche Ränge bedeuten , dann die folgenden Ränge also fortlaufend sind?

Bsp: Nicht 3,3,3,6,7,8 Sondern 3,3,3,4,5,6

Hab mich jetzt mit dem sverweis noch nicht beschäftigt, aber wäre der für diese Tabelle überhaupt sinnvoll?

Mfg Moses

Hallo Moses,
ich habe gerade nicht viel Zeit um die Formel noch zu testen

Folgende Matrix-Formel Für D3 zum runter kopieren
=SUMMENPRODUKT(WENN(Tabelle1.D$3:D$27>0;1/ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)*(Tabelle1.D$3:$D27<Tabelle1.D3);0))+1

Hab mich jetzt mit dem sverweis noch nicht beschäftigt, aber wäre der für diese Tabelle überhaupt sinnvoll?

nein, ich dachte du suchst eine, nach dem Rang sortierte Liste
Gruß Holger

Hallo Echo,

Formel funktioniert, muss nur leider die Buchstaben für jede Spalte manuell ändern.
Beim kopieren ändert das Programm sie zwar automatisch, aber spuckt dann Err:514 aus.

Eine Bitte hätte ich noch und zwar bräuchte ich die Formel noch mit der entgegengesetzten Sortierung, sprich von groß nach klein.

Könntest du mir bei Gelegenheit formulieren, was diese Formel genau macht?

Mfg und vielen Dank

Stefan

Formel funktioniert, muss nur leider die Buchstaben für jede Spalte manuell ändern.

Hallo Stefan,
ich hatte eben nicht die Zeit die Formel genauer zu testen, ein $-Zeichen ist nicht richtig gesetzt, daher die Probleme beim kopieren in den Spalten
alt
=SUMMENPRODUKT(WENN(Tabelle1.D$3:D$27>0;1/ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)*(Tabelle1.D$3: $ D27<Tabelle1.D3);0))+1

Das $-Zeichen etwas weiter rum, dann klappt es auch mit dem kopieren der Matrix-Formel
=SUMMENPRODUKT(WENN(Tabelle1.D$3:D$27>0;1/ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)*(Tabelle1.D$3:D$27<Tabelle1.D3);0))+1

EDIT:
Lesen müsste man können
OK, damit die Rangordnung sich umkehrt Bedarf es nur einer ganz kleinen Änderung:
Ändere < [kleiner] in > [größer] [Rot markiert]
=SUMMENPRODUKT(WENN(Tabelle1.D$3:D$27>0;1/ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)*(Tabelle1.D$3:D$27 < Tabelle1.D3);0))+1
=SUMMENPRODUKT(WENN(Tabelle1.D$3:D$27>0;1/ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)*(Tabelle1.D$3:D$27 > Tabelle1.D3);0))+1
Gruß Holger

Könntest du mir bei Gelegenheit formulieren, was diese Formel genau macht?

Ich werde es versuchen:
=SUMMENPRODUKT(WENN(Tabelle1.D$3:D$27>0;1/ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)*(Tabelle1.D$3:D$27 < Tabelle1.D3);0))+1

Ersste Bedingung: Gezählt werden sollen alle Zahlen die kleiner sind wie die eigene [Tabelle1.D3]
Zweite Bedingung: Alle doppelten Werte soll nur ein mal gezählt werden.
Dadurch ergibt sich der RANG der eigenen Zahl.

Tabelle1.D$3:D$27>0
Dieser Teil sorgt nur dafür, das leere Zellen ignoriert werden.


(Tabelle1.D$3:D$27 < Tabelle1.D3)
Dieser Teil sorgt dafür das nur die Zahlen gezählt werden die kleiner Tabelle1.D3 sind.

Hier wird gezählt:
ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)
Hier wird für jeden einzelnen Wert die Häufigkeit zurück gegeben.
Dadurch das von dieser Zahl immer der Kehrwert gebildet wird "zählt" jeder Wert nur ein mal.
Beispiel:
Ist ein Wert nur ein mal vorhanden ergibt das 1/1 = 1
Ist ein Wert 4 mal vorhanden ergibt sich durch den Kehrwert 1/4 aber 4 Werte von Je 1/4 ergibt 4/4 also wieder 1

SUMMENPRODUKT() addiert zum Schluss alle relevanten Werte

Gruß Holger

Hallo
....WENN(ISTLEER(Tabelle1.D$3:D$27);...

Karo

Hallo Karolus,

weiß nicht genau wie geanu ich das in die Formel einbauen soll.
Es kommt entweder Err:508 oder überall eine Null.

Ich vermute ja ich muss noch einen Teil in die Formel einbauen der besagt, dass auch Werte <0 gewertet werden...

Hallo
=SUMMENPRODUKT(WENN(ISTLEER(Tabelle1.D$3:D$27);0;1/ZÄHLENWENN(Tabelle1.D$3:D$27;Tabelle1.D$3:D$27)*(Tabelle1.D$3:D$27 > Tabelle1.D3)))+1

Karo

Alles klar jetzt funktioniert alles.
Vielen Dank nochmal euch Beiden.

Ich lasse den Thread mal noch offen, wer weiß was noch für Fragestellungen auftauchen