SVERWEIS - elegantere Lösung für Summierung Spalten?

[hylli]

Hi,

ich suche mal wieder eine einfachere/elegantere Lösung.

In einem Arbeitsblatt erfasse ich Werte für die Spalten Januar - Dezember.

Diese Werte sollen auf einem Auswertungsblatt per SVERWEIS aufsummiert werden.

Bisherige Lösung, z.B: für das erste Quartal:

Code: Alles auswählen

=SVERWEIS($B7;$Erfassung_GB1.$A$3:$N$19;3;0)+SVERWEIS($B7;$Erfassung_GB1.$A$3:$N$19;4;0)+SVERWEIS($B7;$Erfassung_GB1.$A$3:$N$19;5;0)

Für das erste Quartal mag das noch übersichtlich aussehen, je mehr Monate dazu kommen, desto unübersichtlicher wird es.

Ich suche mal wieder eine Lösung wie ich das eleganter zusammenfassen kann.

Hylli

PS: Und Danke für den Hinweis hier! Genau dieses Problem hatte ich vorhin auch.

[Karolus]

Hallo

Code: Alles auswählen

=SUMME(INDEX(erfassung;VERGLEICH(B7;kat;0)))

erfassung ist der Name des Bereichs $Erfassung_GB1.$A$3:$N$19
kat ist der Name für den Bereich $Erfassung_GB1.$A$3:$A$19

Edit:
Ich sehe deine SVERWEISe fangen mit dem Index 3 an, in dem fall müsstest du evtl.
erfassung dem Bereich $Erfassung_GB1.$C$3:$N$19 zuordnen ?!
/edit

Karo

[hylli]

Hi,

danke für die Lösung. Die werde ich nachher gleich noch testen.

Mittlerweile gab's eine kleine Änderung im Konzept. Die Auswertung soll monatlich "aufsummiert" laufen, d.h. im Januar nur Januar, im Februar -> Januar + Februar, ...

Zwischenzeitlich habe ich mir mit der Funktion SUMMENPRODUKT behelfen können, allerdings musste ich bei den Auswertungen Monat für Monat eine Spalte hinzufügen, also Auswertung Januar ($C$19 am Ende):

Code: Alles auswählen

=SUMMENPRODUKT(($Erfassung_GB1.$A$4:$Erfassung_GB1.$A$19=$B7)*($Erfassung_GB1.$C$4:$Erfassung_GB1.$C$19))

für Februar ($D$19 am Ende):

Code: Alles auswählen

=SUMMENPRODUKT(($Erfassung_GB1.$A$4:$Erfassung_GB1.$A$19=$B7)*($Erfassung_GB1.$C$4:$Erfassung_GB1.$D$19))

...für alle weiteren Monate entsprechend immer eine Spalte dazu.

Idealerweise sollte man die Formel Monat für Monat weiterkopieren können bzw. idealerweise vergebe ich ein paar Vorgaben und der Rest wird ohne weiteres Zutun erledigt.

Ich bin schon gespannt, wie sich Deine vorgeschlagene Formel so macht.

Hylli

[Karolus]

Hallo
Wenn ich dich richtig verstehe dann kannst du für Januar anfangen mit:

Code: Alles auswählen

=SUMME(INDEX($Erfassung_GB1.$C$4:C$19;VERGLEICH(B7;kat;0)))

Wenn du diese Formel nach rechts kopierst hast du deine fortlaufende Summierung.

(Deine 2.SUMMENPRODUKTformel kann so nicht funktionieren.)

Edit: In deinem Ersten Beitrag war dein Erfassungsbereich noch ab C3
jetzt startet er in Zeile 4 → ändere ggf. die Bereichzuordnung von kat entsprechend.

Gruß Karo