OpenOffice.info

Verfasst: **Sa, 20.07.2013 13:56**

Hallo

Wer kann mir bei folgendem Problem helfen?
In Tabelle2 ist eine 10-spaltige/30-zeilige Tabelle (mit Zahlenwerten) hinterlegt.
In Tabelle1 sind mithilfe des Befehls ADRESSE aus Zelle B1 in Zelle B3 die Adresse $H$1, in Zelle B4 die Adresse $H$30 gespeichert
(Durch anderer B1-Inhalt sind eventuell auch die Adressen $E$1 bzw. $E$30 möglich).
Die entsprechende Spalte H der Tabelle2 soll mit einem VERGLEICH-Befehl durchsucht werden.
Wie kann ich in Zelle B8 auf die entsprechende Spalte der Tabelle2 zugreifen?
Mit festgelegter Spalte H wäre der Befehl VERGLEICH(B6;Tabelle2.$H$1:$H$30;0).

Vielen Dank
jbecker

Verfasst: **Sa, 20.07.2013 16:28**

Prima, dass du gleich 'ne Beispieldatei beigelegt hast

Für's nächste mal: Du kannst die Formel leicht selbst entwickeln.

Ausgangspunkt: deine Formel

Code: Alles auswählen

=VERGLEICH( B6; Tabelle2.$H$1:$H$30; 0 )

Gleichwertig damit ist

Code: Alles auswählen

=VERGLEICH( B6; INDIREKT( "Tabelle2.$H$1:$H$30" ); 0 )

Aufteilen der Zeichenkette in vier Teile:

Code: Alles auswählen

=VERGLEICH( B6; INDIREKT( "Tabelle2." & "$H$1" & ":" & "$H$30" ); 0 )

Ersetzen der fixen Zelladressen durch Referenzen auf B3 und B4

Code: Alles auswählen

=VERGLEICH( B6; INDIREKT( "Tabelle2." & B3 & ":" & B4 ); 0 )

Ersetzen von B3 und B4 durch die jeweiligen Formeln

Code: Alles auswählen

=VERGLEICH( B6; INDIREKT( "Tabelle2." & ADRESSE(1;B1) & ":" & ADRESSE(30;B1) ); 0 )

Gruß
lorbass

Verfasst: **Sa, 20.07.2013 16:51**

Vielen Dank!

OpenOffice.info

Variable Suchmatrix

Variable Suchmatrix

Re: Variable Suchmatrix

Re: Variable Suchmatrix