WENN & VERGLEICH Problem

[Verjigorm]

Hallöchen,

ich habe ein Problem mit folgender Formel:

Code: Alles auswählen

=WENN(VERGLEICH(VERKETTEN(EP$1;",";$A66);coordinates;0)<>"";"vorhanden";"fehlt")

Die Verkettung verknüpft x- und y-Koordinaten damit zum Ergebnis "x,y", was auch wunderbar funktioniert. Nun wollte ich nach diesem verketteten Wert im Bereich "coordinates" suchen und dementsprechend die Zelle füllen.
Solange der Wert vorhanden ist, funktioniert das auch wunderbar, aber egal was ich auch versuche, fehlt der exakte Wert, bekomme ich nur #NV zurück und nicht wie vorgesehen "fehlt".

Jemand einen Tipp parat, woran das liegt? Hab schon die Parameter und die Prüfung gewechselt, aber nichts davon brachte den gewünschten Erfolg.

Vielen Dank im Voraus für jede Antwort

Verji

[F3K Total]

Hi,
ohne Beispieldokument schwierig.
Ins blaue geschossen:
Du kannst den #NV mit

Code: Alles auswählen

NICHT ISTFEHLER

abfangen.

Gruß R

[Verjigorm]

Abfangen ist nur nicht, was ich vorhabe... zumal das ja eigentlich unnötig ist, wenn ich eine WENN-Funktion habe, oder nicht?

[Karolus]

Hallo

Doch, du musst denn Fehler abfangen:

Code: Alles auswählen

=WENN(ISTFEHLER(VERGLEICH(VERKETTEN(EP$1;",";$A66);coordinates;0));"fehlt";"vorhanden")

Karolus

[clag]

Hallo Zusammen,

wird hier nicht mit "ISTFEHLER()" Kanonen auf "#NV" Spatzen geschossen?

#NV ist doch nicht wirklich ein Fehler sondern die korrekte Antwort auf die Abfrage
VERGLEICH(VERKETTEN(EP$1;",";$A66);coordinates;0) nämlich #NV (Wert nicht verfügbar)

Das WENN Formel Konstrukt von Verjigorm ist doch letztlich doppelt gemoppelt und übersetzt lediglich #NV (Wert nicht verfügbar)also "der Wert fehlt" in "fehlt"

@ Verjigorm, die Abfrage auf <>"" ist eher hinderlich und kann gänzlich entfallen da du nur wahr/falsch wissen willst
Wenn es denn unbedingt sein muss sollte man diese 0/1 Logig mit der entsprechenden Funktion tun, zB mit N() oder TYP()
oder man verzichtet gleich auf die unnötige VERGLEICH() Funtion, ein ZÄHLENWENN() tut es hier allemal und ein #NV ist dann eher unwahrscheinlich

1. =WENN(ZÄHLENWENN(coordinates;EP$1&","&$A66)>0;"vorhanden";"fehlt")
2. =WENN(N(VERGLEICH(VERKETTEN(EP$1;",";$A66);coordinates;0));"vorhanden";"fehlt")
3. =WENN(TYP(VERGLEICH(VERKETTEN(EP$1;",";$A66);coordinates;0))=1;"vorhanden";"fehlt")
4. =WENN(ISTFEHLER(VERGLEICH(VERKETTEN(EP$1;",";$A66);coordinates;0));"fehlt";"vorhanden")

@Verjigorm überdenke noch einmal deine Formeln, zu mal du sie scheinbar auch reichlich vervielfachen willst

@ Karolus tut mir ja wirklich Leid, dass ich heute mal deinen Formelvorschlag weiter gekürzt habe

[Karolus]

Hallo

@ Karolus tut mir ja wirklich Leid, dass ich heute mal deinen Formelvorschlag weiter gekürzt habe

Ich werds überleben

Code: Alles auswählen

=WENN(ZÄHLENWENN(coordinates;EP$1&","&$A66);"vorhanden";"fehlt")

Karolus

[clag]

haha

jou... Einer geht immer noch

[Verjigorm]

Zählenwenn scheint genau das zu sein, was ich tatsächlich brauche... hatte schonmal nach Alternativen geguckt, aber da ist mir das nicht eingefallen.

Ich werd gleich mal mein Glück versuchen und danke euch für die Vorschläge und konstruktive Kritik.
Hat mir sehr geholfen, vielen Dank

Verji