OpenOffice.info

Code: Alles auswählen

Function GetLastUsedRow(oSheet as Object) As Integer
' Beschreibung: bestimmt die Nummer der letzten benutzten Zeile

    Dim oCell as Object
    Dim oCursor as Object
    
    oCell = oSheet.getCellByPosition(0,0)
    oCursor = oSheet.createCursorByRange(oCell)
    
    oCursor.gotoEndOfUsedArea(True)
    GetLastUsedRow = oCursor.RangeAddress.EndRow

End Function

Sub Filterergebnis_Zeilen_zaehlen
' Beschreibung: bestimmt die Anzahl der nicht ausgeblendeten Zeilen im Zählbereich
' benötigte Macros: GetLastUsedRow()

    Dim i as Integer 'Laufvariable Zeilen
    Dim oSheet as Object
    Dim oZeilen as Object
    Dim zaehlen as Integer 'Anzahl der sichtbaren Zeilen
    Dim Zaehlbereich_Start as Integer
    Dim Zaehlbereich_Ende as Integer

    oSheet = ThisComponent.CurrentController.ActiveSheet
    
    '--- Festlegen des Zählbereiches
    Zaehlbereich_Start = 1 'Zeilennummer Starts
    Zaehlbereich_Ende = GetLastUsedRow(oSheet)+1 'Zeilennummer Ende
    
    '--- Zählschleife
    zaehlen = 0
    For i = Zaehlbereich_Start to Zaehlbereich_Ende
        oZeilen = oSheet.getCellRangeByName("A"&i).rows
        if oZeilen.isvisible = true then
            zaehlen = zaehlen + 1
        Endif
    Next i
    
    '--- Ausgabe
    MsgBox("Anzahl der sichtbaren Zeilen: " & zaehlen)
    
End Sub